//
// Global Variables
//
// A flag which determines the input mode.
bool isAdmin = false;
// It may be changed every time the device boots up.
const char PASSWORD[] = "033BD94B1168D7E4F0D644C3C95E35BF";

//
// Definitions
//

#define BUFFER_SIZE 64

struct Packet {
  unsigned char size;
  unsigned char type;
  unsigned char data[BUFFER_SIZE];
};

namespace User {
  enum PacketType {
    Hello = 0x00,
    Auth
  };
  void onInput(Packet&);
  void switchToAdmin();
}

namespace Admin {
  enum PacketType {
    Hello = 0x00
  };
  void onInput(Packet&);
}

char recv() {
  while(!Serial.available());
  return Serial.read();
}

void setup() {
  Serial.begin(9600);
  Serial.println("[+] Initialized");
}

void loop() {
  if(Serial.available()) {
    Packet packet;
    packet.size = recv();
    packet.type = recv();
    int i = 0;
    while(true) {
      if(i >= packet.size) break;
      packet.data[i++] = recv();
    }
    if(isAdmin) {
      Admin::onInput(packet);
    } else {
      User::onInput(packet);
    }
  }
}

void User::onInput(Packet &packet) {
  switch(packet.type) {
    case User::PacketType::Hello:
      Serial.print("Hello,");
      Serial.println((char*)packet.data);
      break;
    case User::PacketType::Auth:
      if(!memcmp(packet.data, PASSWORD, sizeof(PASSWORD))) {
        switchToAdmin();
      } else {
        Serial.println("[*] Invalid password");
      }
      break;
    default:
      Serial.print("[*] Invalid packet type: ");
      Serial.println(packet.type);
      break;
  }
}

void Admin::onInput(Packet &packet) {
  switch(packet.type) {
    case Admin::PacketType::Hello:
      Serial.print("You are an admin, ");
      Serial.println((char*)packet.data);
      break;
    default:
      Serial.print("[*] Invalid packet type: ");
      Serial.println(packet.type);
      break;
  }
}

void User::switchToAdmin() {
  isAdmin = true;
  Serial.println("[*] Switched to admin mode");
}