GrainGen.shader
3.01 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
Shader "Hidden/Post FX/Grain Generator"
{
CGINCLUDE
#pragma exclude_renderers d3d11_9x
#pragma target 3.0
#include "UnityCG.cginc"
#include "Common.cginc"
float _Phase;
// Implementation based on Timothy Lottes' "Large Grain"
// Reference code: https://www.shadertoy.com/view/4sSXDW
// Other article of interest: http://devlog-martinsh.blogspot.fr/2013/05/image-imperfections-and-film-grain-post.html
float Noise(float2 n, float x)
{
n += x;
return frac(sin(dot(n.xy, float2(12.9898, 78.233))) * 43758.5453);
}
float Step1(float2 uv, float n)
{
float b = 2.0, c = -12.0;
return (1.0 / (4.0 + b * 4.0 + abs(c))) * (
Noise(uv + float2(-1.0, -1.0), n) +
Noise(uv + float2( 0.0, -1.0), n) * b +
Noise(uv + float2( 1.0, -1.0), n) +
Noise(uv + float2(-1.0, 0.0), n) * b +
Noise(uv + float2( 0.0, 0.0), n) * c +
Noise(uv + float2( 1.0, 0.0), n) * b +
Noise(uv + float2(-1.0, 1.0), n) +
Noise(uv + float2( 0.0, 1.0), n) * b +
Noise(uv + float2( 1.0, 1.0), n)
);
}
float Step2(float2 uv, float n)
{
float b = 2.0, c = 4.0;
return (1.0 / (4.0 + b * 4.0 + abs(c))) * (
Step1(uv + float2(-1.0, -1.0), n) +
Step1(uv + float2( 0.0, -1.0), n) * b +
Step1(uv + float2( 1.0, -1.0), n) +
Step1(uv + float2(-1.0, 0.0), n) * b +
Step1(uv + float2( 0.0, 0.0), n) * c +
Step1(uv + float2( 1.0, 0.0), n) * b +
Step1(uv + float2(-1.0, 1.0), n) +
Step1(uv + float2( 0.0, 1.0), n) * b +
Step1(uv + float2( 1.0, 1.0), n)
);
}
float Step3BW(float2 uv)
{
return Step2(uv, frac(_Phase));
}
float3 Step3(float2 uv)
{
float a = Step2(uv, 0.07 * frac(_Phase));
float b = Step2(uv, 0.11 * frac(_Phase));
float c = Step2(uv, 0.13 * frac(_Phase));
return float3(a, b, c);
}
float4 FragGrain(VaryingsDefault i) : SV_Target
{
float grain = Step3BW(i.uv * float2(192.0, 192.0));
return float4(grain.xxx, 1.0);
}
float4 FragGrainColored(VaryingsDefault i) : SV_Target
{
float3 grain = Step3(i.uv * float2(192.0, 192.0));
return float4(grain, 1.0);
}
ENDCG
SubShader
{
Cull Off ZWrite Off ZTest Always
Pass
{
CGPROGRAM
#pragma vertex VertDefault
#pragma fragment FragGrain
ENDCG
}
Pass
{
CGPROGRAM
#pragma vertex VertDefault
#pragma fragment FragGrainColored
ENDCG
}
}
}